Exportfile for AOT version 1.0 or later
Formatversion: 1

***Element: CLS

; Microsoft Business Solutions-Axapta Class: TabaxPlugin_OpenInAOT, выгружен Понедельник 14.05.2007
; --------------------------------------------------------------------------------
  CLSVERSION 1
  
  CLASS #TabaxPlugin_OpenInAOT
    PROPERTIES
      Name                #TabaxPlugin_OpenInAOT
      Extends             #TabaxPluginBase
      RunOn               #Client
    ENDPROPERTIES
    
    METHODS
      Version: 3
      SOURCE #beforeStringInput
        ##define.prefix("go ")
        #boolean beforeStringInput(Tabax _tabax, str _string)
        #{
        #    str                 fullString;
        #    ;
        #    super(_tabax, _string);
        #
        #    try
        #    {
        #        fullString = WinApi::getWindowText(this.tabax().searchEd().hWnd());
        #        if (strLen(fullString) < strLen(_string) && tabax.strStartsWith(_string, fullString))
        #            fullString = _string;
        #
        #        if (substr(fullString, 1, strLen(#prefix)) == #prefix)
        #        {
        #            if (strLen(fullString) > strLen(#prefix))
        #                this.openInAOT(subStr(fullString, strLen(#prefix) + 1, strLen(_string) - strLen(#prefix)));
        #            return true;        /// Stop line processing
        #        }
        #    }
        #    catch
        #    {
        #        return checkFailed(strFmt("@SYS63093", funcName()));
        #    }
        #
        #    return false;
        #}
      ENDSOURCE
      SOURCE #classDeclaration
        #/// OpenInAOT plugin for tabax
        #///@desc
        #/// Version 0.1
        #/// Input 'go InventTable' to open the \Tables\InventTable node
        #///@see
        #/// See http://www.axaptapedia.com/Editor_scripts_OpenInAOT
        #class TabaxPlugin_OpenInAOT extends TabaxPluginBase
        #{
        #}
      ENDSOURCE
      SOURCE #connected
        #void connected()
        #{
        #    ;
        #    super();
        #
        #    if (hasSecurityKeyAccess(securityKeyNum(SysDevelopment), AccessType::Edit))
        #    {
        #        #subscribe(beforeStringInput)
        #    }
        #}
      ENDSOURCE
      SOURCE #openInAOT
        #boolean openInAOT(str _selectedLine)
        #{
        #    #AOT
        #    TreeNode        treeNode;
        #    str 1           curSymbol;
        #    int             iCopyFrom;
        #    int             iCopyTo;
        #    Set             selectedNodesSet = new Set(Types::Class);
        #    SetIterator     setIterator;
        #    Map             map;
        #
        #    void add2Set(TreeNodePath _path)
        #    {
        #        ;
        #        treeNode = TreeNode::findNode(_path + #AOTRootPath + _selectedLine);
        #        if (treeNode)
        #            selectedNodesSet.add(treeNode);
        #    }
        #    ;
        #
        #    if (_selectedLine)
        #    {
        #        add2Set(#ExtendedDataTypesPath);
        #        add2Set(#BaseEnumsPath);
        #        add2Set(#TablesPath);
        #        add2Set(#ClassesPath);
        #        add2Set(#MacrosPath);
        #
        #        if (selectedNodesSet.elements() == 0)
        #        {
        #            add2Set(#SystemFunctionsPath);
        #            add2Set(#SystemTablesPath);
        #            add2Set(#SystemTypesPath);
        #            add2Set(#SystemEnumsPath);
        #            add2Set(#SystemClassesPath);
        #            add2Set(#ClassesPath + #AOTRootPath + classStr(Global));
        #        }
        #
        #        if (selectedNodesSet.elements() > 0)
        #        {
        #            setIterator = new SetIterator(selectedNodesSet);
        #            setIterator.begin();
        #            if (selectedNodesSet.elements() == 1)
        #            {
        #                treeNode = setIterator.value();
        #            }
        #            else
        #            {
        #                map = new Map(Types::String, Types::String);
        #                while (setIterator.more())
        #                {
        #                    treeNode = setIterator.value();
        #                    map.insert(treeNode.treeNodePath(), treeNode.AOTparent().treeNodeName());
        #                    setIterator.next();
        #                }
        #                treeNode = TreeNode::findNode(pickList(map, "@SYS14719", "@SYS54002"));
        #            }
        #            if (treeNode && treeNode.treeNodePath() != TreeNode::rootNode().treeNodePath())
        #            {
        #                if (SysTreeNode::hasSource(treeNode))
        #                {
        #                    treeNode.AOTedit();
        #                }
        #                else
        #                {
        #                    treeNode.AOTnewWindow();
        #                }
        #                return true;
        #            }
        #        }
        #    }
        #    return false;
        #}
      ENDSOURCE
    ENDMETHODS
  ENDCLASS

***Element: PRN

; Microsoft Business Solutions-Axapta Project : DEV_TabaxPlugin_OpenInAOT unloaded at Понедельник 14.05.2007
; --------------------------------------------------------------------------------
  PROJECTVERSION 2
  
  PROJECT #DEV_TabaxPlugin_OpenInAOT
   SHARED
  PROPERTIES
    Name                #DEV_TabaxPlugin_OpenInAOT
  ENDPROPERTIES
  
    GROUP #Classes
      PROPERTIES
        Name                #Classes
        ProjectGroupType    #Classes
        GroupMask           #
        PreventEditProperties #No
      ENDPROPERTIES
      
      BEGINNODE
        FILETYPE 0
        UTILTYPE 45
        UTILOBJECTID 50193
        NODETYPE 329
        NAME #TabaxPlugin_OpenInAOT
      ENDNODE
      ENDGROUP
      
  ENDPROJECT
  

***Element: END