Exportfile for AOT version 1.0 or later
Formatversion: 1

***Element: JOB

; Microsoft Dynamics Job: hw_addToFavorites unloaded
; --------------------------------------------------------------------------------
  JOBVERSION 1
  
  SOURCE #hw_addToFavorites
    #static void hw_addToFavorites(Args _args)
    #{
    #    #AOT   // AOT macro for easier use
    #
    #    TreeNode            treeNode;
    #    TreeNodeIterator    iterator;
    #    TreeNode            myFavoritesNode;
    #    Menu                myFavoritesMenuNode;
    #    ;
    #
    #    // get the top level user node
    #    treeNode = infolog.userNode();
    #    if (!treeNode)
    #        return;
    #
    #    // get the User Menu List which is the 1st child of the user node
    #    iterator = treeNode.AOTiterator();
    #    treeNode = iterator.next();
    #    if (!treeNode)
    #        return;
    #
    #    // get the "My Favorites" node which is the 1st child of the User Menu List node
    #    iterator = treeNode.AOTiterator();
    #    myFavoritesNode = iterator.next();
    #    if (!myFavoritesNode)
    #        return;
    #
    #    // find the correct MenuItem
    #    // look at the "AOT" macro for the macro names and/or correct spelling
    #    treeNode = TreeNode::findNode(#MenuItemsDisplayPath + #AOTDelimiter + "CustTable");
    #
    #    // you could also write:
    #    //    treeNode = TreeNode::findNode("Menu Items\\Display\\CustTable");
    #
    #    if (!treeNode)
    #        return;
    #
    #    myFavoritesMenuNode = myFavoritesNode;
    #    if (myFavoritesMenuNode)
    #    {
    #        myFavoritesMenuNode.addMenuitem(treeNode);
    #    }
    #}
    #
  ENDSOURCE

***Element: END