Exportfile for AOT version 1.0 or later
Formatversion: 1

***Element: CLS

; Microsoft Dynamics AX Class: DimensionDialog unloaded
; --------------------------------------------------------------------------------
  CLSVERSION 1
  
  CLASS #DimensionDialog
    Id 50007
    PROPERTIES
      Name                #DimensionDialog
      Extends             #RunBaseBatch
      RunOn               #Called from
    ENDPROPERTIES
    
    METHODS
      Version: 3
      SOURCE #caption
        #public ClassDescription caption()
        #{
        #    ClassDescription ret;
        #
        #    ret = "Dimension dialog";
        #
        #    return ret;
        #}
      ENDSOURCE
      SOURCE #classDeclaration
        #// This is a framework class. Customizing this class may cause problems with future upgrades to the software.
        #class DimensionDialog extends RunBaseBatch
        #{
        #    SysDimension        selectedDimension;
        #    Map                 dimensionAcceptedValues;
        #    FormComboBoxControl formComboBoxControl;
        #
        #    // Dialog fields
        #    DialogField dimension;
        #
        #    #define.CurrentVersion(1)
        #    #define.Version1(1)
        #    #localmacro.CurrentList
        #        selectedDimension
        #    #endmacro
        #}
      ENDSOURCE
      SOURCE #dialog
        #public Object dialog()
        #{
        #    DialogRunbase       dialog;
        #    ;
        #    dialog = super();
        #
        #    dimension = dialog.addField(typeid(SysDimension));
        #
        #    return dialog;
        #}
        #
      ENDSOURCE
      SOURCE #dialogPostRun
        #public void dialogPostRun(DialogRunbase _dialog)
        #{
        #    FormRun             formRun;
        #    SysDictEnum         dictEnum;
        #    int                 i, j, enumCount;
        #    Set                 removeValues;
        #    ;
        #    removeValues = new Set(Types::String);
        #    removeValues.add("Department");
        #    removeValues.add("Purpose");
        #
        #    dimensionAcceptedValues = new Map(Types::Integer, Types::Enum);
        #
        #    dictEnum = new SysDictEnum(enumNum(SysDimension));
        #
        #    enumCount = dictEnum.values();
        #
        #    super(_dialog);
        #    formRun = _dialog.formRun();
        #    formComboBoxControl = formRun.design().controlName(dimension.name());
        #    formComboBoxControl.clear();
        #
        #    for (i=0; i<enumCount; i++)
        #    {
        #        if (removeValues.in(dictEnum.index2Label(i)))
        #        {
        #            continue;
        #        }
        #        formComboBoxControl.add(dictEnum.index2Label(i));
        #        dimensionAcceptedValues.insert(j, dictEnum.index2Value(i));
        #        j++;
        #    }
        #    formComboBoxControl.selection(0);
        #}
      ENDSOURCE
      SOURCE #getFromDialog
        #public boolean getFromDialog()
        #{
        #    SysDictEnum     dictEnum;
        #    boolean ret;
        #
        #    ret = super();
        #
        #    dictEnum = new SysDictEnum(enumNum(SysDimension));
        #
        #    info(strfmt("You selected %1",dictEnum.index2Label(dimensionAcceptedValues.lookup(formComboBoxControl.selection()))));
        #
        #    return ret;
        #}
      ENDSOURCE
      SOURCE #pack
        #public container pack()
        #{
        #    return [#CurrentVersion,#CurrentList];
        #}
      ENDSOURCE
      SOURCE #unpack
        #public boolean unpack(container packedClass)
        #{
        #    Version version = RunBase::getVersion(packedClass);
        #;
        #    switch (version)
        #    {
        #        case #CurrentVersion:
        #            [version,#CurrentList] = packedClass;
        #            break;
        #        default:
        #            return false;
        #    }
        #
        #    return true;
        #}
      ENDSOURCE
      SOURCE #construct
        #server static DimensionDialog construct()
        #{
        #    return new DimensionDialog();
        #}
      ENDSOURCE
      SOURCE #main
        #static void main(Args args)
        #{
        #    DimensionDialog     dimensionDialog;
        #    ;
        #    dimensionDialog = DimensionDialog::construct();
        #
        #    if (dimensionDialog.prompt())
        #    {
        #        dimensionDialog.run();
        #    }
        #}
        #
      ENDSOURCE
    ENDMETHODS
  ENDCLASS

***Element: PRN

; Microsoft Dynamics AX Project : RemoveDimensionInDialog unloaded
; --------------------------------------------------------------------------------
  PROJECTVERSION 2
  
  PROJECT #RemoveDimensionInDialog
   PRIVATE
  PROPERTIES
    Name                #RemoveDimensionInDialog
  ENDPROPERTIES
  
    PROJECTCLASS ProjectNode
    BEGINNODE
      FILETYPE 0
      UTILTYPE 45
      UTILOBJECTID 50007
      NODETYPE 329
      NAME #DimensionDialog
    ENDNODE
  ENDPROJECT
  

***Element: END